From c87c0f21441a39d9dbfbd1c3a026075b02907dc2 Mon Sep 17 00:00:00 2001
From: Shawn Dellysse <sdellysse@gmail.com>
Date: Mon, 27 Mar 2017 20:18:28 -0400
Subject: [PATCH] messenger-for-desktop: init at 2.0.6

---
 lib/maintainers.nix                           |   1 +
 .../messenger-for-desktop/default.nix         | 104 ++++++++++++++++++
 pkgs/top-level/all-packages.nix               |   2 +
 3 files changed, 107 insertions(+)
 create mode 100644 pkgs/applications/networking/instant-messengers/messenger-for-desktop/default.nix

diff --git a/lib/maintainers.nix b/lib/maintainers.nix
index 087c2463957f..4f5ee4b0801a 100644
--- a/lib/maintainers.nix
+++ b/lib/maintainers.nix
@@ -462,6 +462,7 @@
   sepi = "Raffael Mancini <raffael@mancini.lu>";
   seppeljordan = "Sebastian Jordan <sebastian.jordan.mail@googlemail.com>";
   shanemikel = "Shane Pearlman <shanemikel1@gmail.com>";
+  shawndellysse = "Shawn Dellysse <sdellysse@gmail.com>";
   sheenobu = "Sheena Artrip <sheena.artrip@gmail.com>";
   sheganinans = "Aistis Raulinaitis <sheganinans@gmail.com>";
   shell = "Shell Turner <cam.turn@gmail.com>";
diff --git a/pkgs/applications/networking/instant-messengers/messenger-for-desktop/default.nix b/pkgs/applications/networking/instant-messengers/messenger-for-desktop/default.nix
new file mode 100644
index 000000000000..f12a14c5c926
--- /dev/null
+++ b/pkgs/applications/networking/instant-messengers/messenger-for-desktop/default.nix
@@ -0,0 +1,104 @@
+{
+  stdenv, fetchurl, dpkg, alsaLib, atk, cairo, cups, curl, dbus, expat,
+  fontconfig, freetype, glib, gnome2, libnotify, nspr, nss, systemd, xorg
+}:
+
+with stdenv.lib;
+
+let
+
+  version = "2.0.6";
+
+  rpath = makeLibraryPath [
+    alsaLib
+    atk
+    cairo
+    cups
+    curl
+    dbus
+    expat
+    fontconfig
+    freetype
+    glib
+    gnome2.GConf
+    gnome2.gdk_pixbuf
+    gnome2.gtk
+    gnome2.pango
+    libnotify
+    nspr
+    nss
+    stdenv.cc.cc
+    systemd
+
+    xorg.libxkbfile
+    xorg.libX11
+    xorg.libXcomposite
+    xorg.libXcursor
+    xorg.libXdamage
+    xorg.libXext
+    xorg.libXfixes
+    xorg.libXi
+    xorg.libXrandr
+    xorg.libXrender
+    xorg.libXtst
+    xorg.libXScrnSaver
+  ] + ":${stdenv.cc.cc.lib}/lib64";
+
+  src =
+    if stdenv.system == "x86_64-linux" then
+      fetchurl {
+        url = "https://github.com/aluxian/Messenger-for-Desktop/releases/download/v2.0.6/messengerfordesktop-2.0.6-linux-amd64.deb";
+        sha256 = "bf3f3ed9ac46ceb4b7dffbeb33c7d15bbcbfcdd141c4dbfbb620e8bfefae906b";
+      }
+    else
+      throw "Messenger for Desktop is not supported on ${stdenv.system}";
+
+in stdenv.mkDerivation {
+  name = "messenger-for-desktop-${version}";
+
+  inherit src;
+
+  buildInputs = [ dpkg ];
+  unpackPhase = "true";
+  buildCommand = ''
+    mkdir -p $out
+    dpkg -x $src $out
+
+    mv $out/usr/share $out/share
+    mv $out/opt/messengerfordesktop $out/libexec
+    rmdir $out/usr $out/opt
+
+    chmod -R g-w $out
+
+    # patch the binaries
+    for file in $(find $out -type f \( -perm /0111 -o -name \*.so\* \) ); do
+      patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" "$file" || true
+      patchelf --set-rpath ${rpath}:$out/libexec $file || true
+    done
+
+    # add symlink to bin
+    mkdir -p $out/bin
+    ln -s $out/libexec/messengerfordesktop $out/bin/messengerfordesktop
+
+    # Fix the desktop link
+    substituteInPlace $out/share/applications/messengerfordesktop.desktop                 \
+      --replace /opt/messengerfordesktop/messengerfordesktop $out/bin/messengerfordesktop 
+  '';
+
+  meta = {
+    description = "Bring messenger.com to your Linux desktop.";
+    longDescription = ''
+      A simple & beautiful desktop client for Facebook Messenger. Chat without
+      distractions on OS X, Windows and Linux. Not affiliated with Facebook.
+      This is NOT an official product.
+    '';
+    homepage = https://messengerfordesktop.org;
+    license = licenses.mit;
+    maintainers = [
+      maintainers.shawndellysse
+    ];
+    platforms = [
+      "x86_64-linux"
+    ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index aa06bf990cc9..6cac7bed908c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -18392,4 +18392,6 @@ with pkgs;
   hy = callPackage ../development/interpreters/hy {};
 
   ghc-standalone-archive = callPackage ../os-specific/darwin/ghc-standalone-archive { inherit (darwin) cctools; };
+
+  messenger-for-desktop = callPackage ../applications/networking/instant-messengers/messenger-for-desktop {};
 }