Merge pull request #242506 from GaetanLepage/exputils

pkgs/development/python-modules/experiment-utilities/default.nix

@@ -0,0 +1,69 @@
+{ lib
+, buildPythonPackage
+, cloudpickle
+, dill
+, fasteners
+, fetchFromGitLab
+, qgrid
+, ipywidgets
+, odfpy
+, scipy
+, plotly
+, pytestCheckHook
+, pyyaml
+, tabulate
+, tensorboard
+, torch
+}:
+
+buildPythonPackage rec {
+  pname = "experiment-utilities";
+  version = "0.3.4";
+
+  src = fetchFromGitLab {
+    owner = "creinke";
+    repo = "exputils";
+    domain = "gitlab.inria.fr";
+    rev = "refs/tags/version_${version}";
+    hash = "sha256-zjmmLUpGjUhpw2+stLJE6cImesnBSvrcid5bHMftX/Q=";
+  };
+
+  # This dependency constraint (<=7.6.5) was due to a bug in qgrid that has been patched in its
+  # owned derivation
+  postPatch = ''
+    substituteInPlace setup.cfg \
+      --replace "ipywidgets >= 7.5.1,<= 7.6.5" "ipywidgets >= 7.5.1"
+  '';
+
+  propagatedBuildInputs = [
+    cloudpickle
+    dill
+    fasteners
+    ipywidgets
+    odfpy
+    plotly
+    pyyaml
+    qgrid
+    scipy
+    tabulate
+    tensorboard
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    torch
+  ];
+
+  disabledTests = [
+    "test_experimentstarter"
+  ];
+
+  pythonImportsCheck = [ "exputils" ];
+
+  meta = with lib; {
+    description = "Various tools to run scientific computer experiments.";
+    homepage = "https://gitlab.inria.fr/creinke/exputils";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ GaetanLepage ];
+  };
+}

pkgs/development/python-modules/qgrid/default.nix

@@ -0,0 +1,53 @@
+{ lib
+, buildPythonPackage
+, fetchpatch
+, fetchPypi
+, ipywidgets
+, notebook
+, pandas
+, pytestCheckHook
+}:
+
+buildPythonPackage rec {
+  pname = "qgrid";
+  version = "1.3.1";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-/or1tQgzCE3AtqJlzRrHuDfAPA+FIRUBY1YNzneNcRw=";
+  };
+
+  patches = [
+    # Fixes compatibility of qgrid with ipywidgets >= 8.0.0
+    # See https://github.com/quantopian/qgrid/pull/331
+    (fetchpatch {
+      url = "https://github.com/quantopian/qgrid/pull/331/commits/8cc50d5117d4208a9dd672418021c59898e2d1b2.patch";
+      hash = "sha256-+NLz4yBUGUXKyukPVE4PehenPzjnfljR5RAX7CEtpV4=";
+    })
+  ];
+
+  propagatedBuildInputs = [
+    ipywidgets
+    notebook
+    pandas
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  # Those tests are also failing upstream
+  disabledTests = [
+    "test_edit_date"
+    "test_period_object_column"
+  ];
+
+  pythonImportsCheck = [ "qgrid" ];
+
+  meta = with lib; {
+    description = "An interactive grid for sorting, filtering, and editing DataFrames in Jupyter notebooks";
+    homepage = "https://github.com/quantopian/qgrid";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ GaetanLepage ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -3453,6 +3453,8 @@ self: super: with self; {
 
   expecttest = callPackage ../development/python-modules/expecttest { };
 
+  experiment-utilities = callPackage ../development/python-modules/experiment-utilities { };
+
   expiring-dict = callPackage ../development/python-modules/expiring-dict { };
 
   expiringdict = callPackage ../development/python-modules/expiringdict { };
@@ -10503,6 +10505,8 @@ self: super: with self; {
 
   qds_sdk = callPackage ../development/python-modules/qds_sdk { };
 
+  qgrid = callPackage ../development/python-modules/qgrid { };
+
   qiling = callPackage ../development/python-modules/qiling { };
 
   qimage2ndarray = callPackage ../development/python-modules/qimage2ndarray { };