nordic-dev.net/nixpkgs
nordic-dev.net/nixpkgs
2
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-10-31 22:51:22 +00:00
Code Issues Packages Projects Releases Wiki Activity

sddm-chili-theme: init at 0.1.5

Browse Source
This commit is contained in:
Finn Krein 2023-04-01 17:25:33 +02:00 committed by Sandro Jäckel
parent 044d653f7a
commit ab01576cb1
No known key found for this signature in database
GPG Key ID: 3AF5A43A3EECC2E5
2 changed files with 63 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

61
pkgs/data/themes/chili-sddm/default.nix Normal file
View File

@ -0,0 +1,61 @@
{ lib
, stdenv
, fetchFromGitHub
, qtgraphicaleffects
, themeConfig ? { }
}:
let
customToString = x: if builtins.isBool x then lib.boolToString x else toString x;
configLines = lib.mapAttrsToList (name: value: lib.nameValuePair name value) themeConfig;
configureTheme = "cp theme.conf theme.conf.orig \n" +
(lib.concatMapStringsSep "\n"
(configLine:
"grep -q '^${configLine.name}=' theme.conf || echo '${configLine.name}=' >> \"$1\"\n" +
"sed -i -e 's/^${configLine.name}=.*$/${configLine.name}=${
lib.escape [ "/" "&" "\\"] (customToString configLine.value)
}/' theme.conf"
)
configLines);
in
stdenv.mkDerivation {
pname = "sddm-chili-theme";
version = "0.1.5";
src = fetchFromGitHub {
owner = "MarianArlt";
repo = "sddm-chili";
rev = "6516d50176c3b34df29003726ef9708813d06271";
sha256 = "036fxsa7m8ymmp3p40z671z163y6fcsa9a641lrxdrw225ssq5f3";
};
propagatedBuildInputs = [
qtgraphicaleffects
];
dontWrapQtApps = true;
preInstall = configureTheme;
postInstall = ''
mkdir -p $out/share/sddm/themes/chili
mv * $out/share/sddm/themes/chili/
'';
postFixup = ''
mkdir -p $out/nix-support
echo ${qtgraphicaleffects} >> $out/nix-support/propagated-user-env-packages
'';
meta = with lib; {
license = licenses.gpl3;
maintainers = with lib.maintainers; [ sents ];
homepage = "https://github.com/MarianArlt/sddm-chili";
description = "The chili login theme for SDDM";
longDescription = ''
Chili is hot, just like a real chili!
Spice up the login experience for your users, your family and yourself.
Chili reduces all the clutter and leaves you with a clean, easy to use, login interface with a modern yet classy touch.
'';
};
}

2
pkgs/top-level/all-packages.nix
View File

@ -27060,6 +27060,8 @@ with pkgs;
schedtool = callPackage ../os-specific/linux/schedtool { };
sddm-chili-theme = libsForQt5.callPackage ../data/themes/chili-sddm { };
sdparm = callPackage ../os-specific/linux/sdparm { };
sdrangel = libsForQt5.callPackage ../applications/radio/sdrangel { };