nordic-dev.net/nixpkgs
nordic-dev.net/nixpkgs
2
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-10-31 22:51:22 +00:00
Code Issues Packages Projects Releases Wiki Activity

bitbake-language-server: init at 0.0.6

Browse Source 
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
This commit is contained in:
Otavio Salvador 2023-09-24 11:32:28 -03:00
parent c182df2e68
commit 97d158a095
1 changed files with 63 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

63
pkgs/by-name/bi/bitbake-language-server/package.nix Normal file
View File

@ -0,0 +1,63 @@
{ lib
, nix-update-script
, python3
, fetchFromGitHub
, cmake
, ninja
}:
let
tree-sitter-bitbake = fetchFromGitHub {
owner = "amaanq";
repo = "tree-sitter-bitbake";
rev = "v1.0.0";
hash = "sha256-HfWUDYiBCmtlu5fFX287BSDHyCiD7gqIVFDTxH5APAE=";
};
in
python3.pkgs.buildPythonApplication rec {
pname = "bitbake-language-server";
version = "0.0.6";
format = "pyproject";
src = fetchFromGitHub {
owner = "Freed-Wu";
repo = pname;
rev = version;
hash = "sha256-UOeOvaQplDn7jM+3sUZip1f05TbczoaRQKMxVm+euDU=";
};
nativeBuildInputs = with python3.pkgs; [
cmake
ninja
pathspec
pyproject-metadata
scikit-build-core
setuptools-scm
];
propagatedBuildInputs = with python3.pkgs; [
lsprotocol
platformdirs
pygls
tree-sitter
];
SETUPTOOLS_SCM_PRETEND_VERSION = version;
# The scikit-build-core runs CMake internally so we must let it run the configure step itself.
dontUseCmakeConfigure = true;
SKBUILD_CMAKE_ARGS = lib.strings.concatStringsSep ";" [
"-DFETCHCONTENT_FULLY_DISCONNECTED=ON"
"-DFETCHCONTENT_QUIET=OFF"
"-DFETCHCONTENT_SOURCE_DIR_TREE-SITTER-BITBAKE=${tree-sitter-bitbake}"
];
passthru.updateScript = nix-update-script { };
meta = with lib; {
description = "Language server for bitbake";
homepage = "https://github.com/Freed-Wu/bitbake-language-server";
changelog = "https://github.com/Freed-Wu/bitbake-language-server/releases/tag/v${version}";
license = licenses.gpl3;
maintainers = with maintainers; [ otavio ];
};
}