nordic-dev.net/nixpkgs
nordic-dev.net/nixpkgs
2
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-11-25 00:12:56 +00:00
Code Issues Packages Projects Releases Wiki Activity

stackit-cli: init at 0.1.0-prerelease.2

Browse Source
This commit is contained in:
DerRockWolf 2024-03-17 15:31:37 +01:00
parent 2f600c8e7a
commit 971426ad49
No known key found for this signature in database
1 changed files with 80 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

80
pkgs/by-name/st/stackit-cli/package.nix Normal file
View File

@ -0,0 +1,80 @@
{ lib
, buildGoModule
, fetchFromGitHub
, installShellFiles
, makeWrapper
, less
, xdg-utils
, testers
, runCommand
, stackit-cli
}:
buildGoModule rec {
pname = "stackit-cli";
version = "0.1.0-prerelease.2";
src = fetchFromGitHub {
owner = "stackitcloud";
repo = "stackit-cli";
rev = "v${version}";
hash = "sha256-GS3ZXarhXs1xuVmiLPMrrzXnO79R1+2va0x7N7CKNjQ=";
};
vendorHash = "sha256-Cill5hq8KVeKGRX2u9oIudi/s8XHIW5C8sgbTshrLY4=";
subPackages = [ "." ];
CGO_ENABLED = 0;
ldflags = [
"-s"
"-w"
"-X main.version=${version}"
];
nativeBuildInputs = [ installShellFiles makeWrapper ];
preCheck = ''
export HOME=$TMPDIR # needed because the binary always creates a dir & config file
'';
postInstall = ''
export HOME=$TMPDIR # needed because the binary always creates a dir & config file
mv $out/bin/{${pname},stackit} # rename the binary
installShellCompletion --cmd stackit --bash <($out/bin/stackit completion bash)
installShellCompletion --cmd stackit --zsh <($out/bin/stackit completion zsh)
installShellCompletion --cmd stackit --fish <($out/bin/stackit completion fish)
# Use this instead, once https://github.com/stackitcloud/stackit-cli/issues/153 is fixed:
# installShellCompletion --cmd stackit \
# --bash <($out/bin/stackit completion bash) \
# --zsh <($out/bin/stackit completion zsh) \
# --fish <($out/bin/stackit completion fish)
# Ensure that all 3 completion scripts exist AND have content (should be kept for regression testing)
[ $(find $out/share -not -empty -type f | wc -l) -eq 3 ]
'';
postFixup = ''
wrapProgram $out/bin/stackit \
--suffix PATH : ${lib.makeBinPath [ less xdg-utils ]}
'';
nativeCheckInputs = [ less ];
passthru.tests = {
version = testers.testVersion {
package = stackit-cli;
command = "HOME=$TMPDIR stackit --version";
};
};
meta = with lib; {
description = "CLI to manage STACKIT cloud services";
homepage = "https://github.com/stackitcloud/stackit-cli";
changelog = "https://github.com/stackitcloud/stackit-cli/releases/tag/v${version}";
license = licenses.asl20;
maintainers = with maintainers; [ DerRockWolf ];
mainProgram = "stackit";
};
}