nccl-tests: init at 2.13.6

pkgs/development/libraries/science/math/nccl/tests.nix

@@ -0,0 +1,54 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, which
+, cudaPackages
+, mpiSupport ? false
+, mpi
+}:
+
+assert mpiSupport -> mpi != null;
+
+with cudaPackages;
+
+cudaPackages.backendStdenv.mkDerivation rec {
+
+  pname = "nccl-tests";
+  version = "2.13.6";
+
+  src = fetchFromGitHub {
+    owner = "NVIDIA";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-3gSBQ0g6mnQ/MFXGflE+BqqrIUoiBgp8+fWRQOvLVkw=";
+  };
+
+  nativeBuildInputs = [ which cuda_nvcc ];
+
+  buildInputs = [
+    cuda_cudart
+    nccl
+  ] ++ lib.optional mpiSupport mpi;
+
+  makeFlags = [
+    "CUDA_HOME=${cudatoolkit}"
+    "NCCL_HOME=${nccl}"
+  ] ++ lib.optionals mpiSupport [
+    "MPI=1"
+  ];
+
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -r build/* $out/bin/
+  '';
+
+  meta = with lib; {
+    description = "Tests to check both the performance and the correctness of NVIDIA NCCL operations.";
+    homepage = "https://github.com/NVIDIA/nccl-tests";
+    platforms = [ "x86_64-linux" ];
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ jmillerpdt ];
+  };
+}

pkgs/top-level/cuda-packages.nix

@@ -47,6 +47,8 @@ let
 
     nccl = final.callPackage ../development/libraries/science/math/nccl { };
 
+    nccl-tests = final.callPackage ../development/libraries/science/math/nccl/tests.nix { };
+
     autoAddOpenGLRunpathHook = final.callPackage ( { makeSetupHook, addOpenGLRunpath }:
       makeSetupHook {
         name = "auto-add-opengl-runpath-hook";