From 5b54050136016972de795ae8bff95fff60b2f425 Mon Sep 17 00:00:00 2001
From: tahanonu <tochipreciousahan@gmail.com>
Date: Fri, 12 Jul 2024 00:03:57 +0100
Subject: [PATCH] python312Packages.pip-chill: init at 1.0.3

Release: https://github.com/rbanffy/pip-chill/releases/tag/v1.0.3
---
 .../python-modules/pip-chill/default.nix      | 47 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 49 insertions(+)
 create mode 100644 pkgs/development/python-modules/pip-chill/default.nix

diff --git a/pkgs/development/python-modules/pip-chill/default.nix b/pkgs/development/python-modules/pip-chill/default.nix
new file mode 100644
index 000000000000..7a32efc1c013
--- /dev/null
+++ b/pkgs/development/python-modules/pip-chill/default.nix
@@ -0,0 +1,47 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildPythonPackage,
+  setuptools,
+  pip,
+  pythonAtLeast,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pip-chill";
+  version = "1.0.3";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "rbanffy";
+    repo = "pip-chill";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-oWq3UWBL5nsCBUkaElashZKvm7pN3StJNubgU++8YFs=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = lib.optionals (pythonAtLeast "3.12") [ setuptools ];
+
+  nativeCheckInputs = [
+    pip
+    pytestCheckHook
+  ];
+
+  preCheck = ''
+    substituteInPlace tests/test_pip_chill.py \
+      --replace-fail "pip_chill/cli.py" "${placeholder "out"}/bin/pip-chill"
+  '';
+
+  pythonImportsCheck = [ "pip_chill" ];
+
+  meta = {
+    description = "A more relaxed `pip freeze`";
+    homepage = "https://github.com/rbanffy/pip-chill";
+    changelog = "https://github.com/rbanffy/pip-chill/releases/tag/v${version}";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ tochiaha ];
+    mainProgram = "pip-chill";
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 914324d07b82..5561880e5428 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -10019,6 +10019,8 @@ self: super: with self; {
 
   pip-api = callPackage ../development/python-modules/pip-api { };
 
+  pip-chill = callPackage ../development/python-modules/pip-chill { };
+
   pip-tools = callPackage ../development/python-modules/pip-tools { };
 
   pip-requirements-parser = callPackage ../development/python-modules/pip-requirements-parser { };