diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 8d048444d8d6..833644c5a974 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -8268,6 +8268,12 @@
     githubId = 16481032;
     name = "Kiba Fox";
   };
+  kidanger = {
+    email = "angerj.dev@gmail.com";
+    github = "kidanger";
+    githubId = 297479;
+    name = "Jérémy Anger";
+  };
   kidd = {
     email = "raimonster@gmail.com";
     github = "kidd";
diff --git a/pkgs/applications/graphics/vpv/default.nix b/pkgs/applications/graphics/vpv/default.nix
new file mode 100644
index 000000000000..724dd25f8f88
--- /dev/null
+++ b/pkgs/applications/graphics/vpv/default.nix
@@ -0,0 +1,63 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, pkg-config
+, libpng
+, libtiff
+, libjpeg
+, SDL2
+, gdal
+, octave
+, rustPlatform
+, cargo
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vpv";
+  version = "0.8.1";
+
+  src = fetchFromGitHub {
+    owner = "kidanger";
+    repo = "vpv";
+    rev = "v${finalAttrs.version}";
+    sha256 = "0cphgq1pqmwrjdmq524j5y522iaq6yhp2dpjdv0a3f9558dayxix";
+  };
+
+  cargoRoot = "src/fuzzy-finder";
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    src = finalAttrs.src;
+    sourceRoot = "source/src/fuzzy-finder";
+    hash = "sha256-CDKlmwA2Wj78xPaSiYPmIJ7xmiE5Co+oGGejZU3v1zI=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    rustPlatform.cargoSetupHook
+    cargo
+  ];
+
+  buildInputs = [
+    libpng
+    libtiff
+    libjpeg
+    SDL2
+    gdal
+    octave
+  ];
+
+  cmakeFlags = [
+    "-DUSE_GDAL=ON"
+    "-DUSE_OCTAVE=ON"
+    "-DVPV_VERSION=v${finalAttrs.version}"
+    "-DBUILD_TESTING=ON"
+  ];
+
+  meta = {
+    homepage = "https://github.com/kidanger/vpv";
+    description = "Image viewer for image processing experts";
+    maintainers = [ lib.maintainers.kidanger ];
+    license = lib.licenses.gpl3;
+    broken = stdenv.isDarwin; # the CMake expects the SDL2::SDL2main target for darwin
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index e2d6bb346076..a518418cd3b8 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -34913,6 +34913,8 @@ with pkgs;
     autoreconfHook = buildPackages.autoreconfHook269;
   };
 
+  vpv = callPackage ../applications/graphics/vpv { };
+
   vsce = callPackage ../development/tools/vsce { };
 
   vscode = callPackage ../applications/editors/vscode/vscode.nix { };