python39Packages.pyeclib: init at 1.6.0

pkgs/development/python-modules/pyeclib/default.nix

@@ -0,0 +1,35 @@
+{ lib, buildPythonPackage, fetchPypi, liberasurecode, six }:
+
+buildPythonPackage rec {
+  pname = "pyeclib";
+  version = "1.6.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-gBHjHuia5/uZymkWZgyH4BCEZqmWK9SXowAQIJdOO7E=";
+  };
+
+  postPatch = ''
+    # patch dlopen call
+    substituteInPlace src/c/pyeclib_c/pyeclib_c.c \
+      --replace "liberasurecode.so" "${liberasurecode}/lib/liberasurecode.so"
+  '';
+
+  preBuild = ''
+    # required for the custom find_library function in setup.py
+    export LD_LIBRARY_PATH="${lib.makeLibraryPath [ liberasurecode ]}"
+  '';
+
+  buildInputs = [ liberasurecode ];
+
+  checkInputs = [ six ];
+
+  pythonImportsCheck = [ "pyeclib" ];
+
+  meta = with lib; {
+    description = "This library provides a simple Python interface for implementing erasure codes.";
+    homepage = "https://github.com/openstack/pyeclib";
+    license = licenses.bsd2;
+    maintainers = teams.openstack.members;
+  };
+}

pkgs/top-level/python-packages.nix

@@ -6194,6 +6194,8 @@ in {
 
   pyechonest = callPackage ../development/python-modules/pyechonest { };
 
+  pyeclib = callPackage ../development/python-modules/pyeclib { };
+
   pyeconet = callPackage ../development/python-modules/pyeconet { };
 
   pyedimax = callPackage ../development/python-modules/pyedimax { };