From 674fcaeea11351bdd016388bcae3d510c8687e7b Mon Sep 17 00:00:00 2001
From: qwqawawow <eihqnh@outlook.com>
Date: Wed, 27 Nov 2024 18:30:51 +0800
Subject: [PATCH] poac: 0.5.1 -> 0.10.1

---
 pkgs/by-name/po/poac/package.nix        |  73 +++++++++++++++++
 pkgs/development/tools/poac/default.nix | 101 ------------------------
 pkgs/top-level/all-packages.nix         |   4 -
 3 files changed, 73 insertions(+), 105 deletions(-)
 create mode 100644 pkgs/by-name/po/poac/package.nix
 delete mode 100644 pkgs/development/tools/poac/default.nix

diff --git a/pkgs/by-name/po/poac/package.nix b/pkgs/by-name/po/poac/package.nix
new file mode 100644
index 000000000000..cbbab08da4f3
--- /dev/null
+++ b/pkgs/by-name/po/poac/package.nix
@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  tbb_2021_11,
+  libgit2,
+  curl,
+  fmt,
+  nlohmann_json,
+  pkg-config,
+}:
+
+let
+  toml11 = fetchFromGitHub rec {
+    owner = "ToruNiina";
+    repo = "toml11";
+    version = "4.2.0";
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-NUuEgTpq86rDcsQnpG0IsSmgLT0cXhd1y32gT57QPAw=";
+  };
+in
+stdenv.mkDerivation rec {
+  pname = "poac";
+  version = "0.10.1";
+
+  src = fetchFromGitHub {
+    owner = "poac-dev";
+    repo = pname;
+    rev = "refs/tags/${version}";
+    sha256 = "sha256-uUVNM70HNJwrr38KB+44fNvLpWihoKyDpRj7d7kbo7k=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    libgit2
+    fmt
+    tbb_2021_11
+    nlohmann_json
+    curl
+  ];
+
+  preConfigure = ''
+    #Skip git clone toml11
+    substituteInPlace Makefile \
+       --replace-fail "git clone" "\#git clone"
+    substituteInPlace Makefile \
+       --replace-fail "git -C" "\#git -c"
+  '';
+
+  preBuild = ''
+    mkdir -p build-out/DEPS/
+    cp -rf ${toml11} build-out/DEPS/toml11
+  '';
+
+  makeFlags = [ "RELEASE=1" ];
+
+  installFlags = [ "PREFIX=${placeholder "out"}" ];
+
+  meta = {
+    broken = (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64);
+    homepage = "https://poac.dev";
+    description = "A package manager and build system for C++";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.qwqawawow ];
+    platforms = lib.platforms.unix;
+    mainProgram = "poac";
+  };
+}
diff --git a/pkgs/development/tools/poac/default.nix b/pkgs/development/tools/poac/default.nix
deleted file mode 100644
index d6a1ad39bdaf..000000000000
--- a/pkgs/development/tools/poac/default.nix
+++ /dev/null
@@ -1,101 +0,0 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, cmake
-, cpm-cmake
-, git
-, git2-cpp
-, cacert
-, boost179
-, icu
-, libarchive
-, libgit2
-, lz4
-, mitama-cpp-result
-, ninja
-, openssl_3
-, package-project-cmake
-, spdlog
-}:
-
-let
-  glob = fetchFromGitHub {
-    owner = "p-ranav";
-    repo = "glob";
-    rev = "v0.0.1";
-    sha256 = "sha256-2y+a7YFBiYX8wbwCCWw1Cm+SFoXGB3ZxLPi/QdZhcdw=";
-  };
-
-  structopt = fetchFromGitHub {
-    owner = "p-ranav";
-    repo = "structopt";
-    rev = "e9722d3c2b52cf751ebc1911b93d9649c4e365cc";
-    sha256 = "sha256-jIfKUyY2QQ2/donywwlz65PY8u7xODGoG6SlNtUhwkg=";
-  };
-
-  toml11 = fetchFromGitHub {
-    owner = "ToruNiina";
-    repo = "toml11";
-    rev = "9086b1114f39a8fb10d08ca704771c2f9f247d02";
-    sha256 = "sha256-fHUElHO4ckNQq7Q88GdbHGxfaAvWoWtGB0eD9y2MnLo=";
-  };
-in
-stdenv.mkDerivation rec {
-  pname = "poac";
-  version = "0.5.1";
-
-  src = fetchFromGitHub {
-    owner = "poacpm";
-    repo = pname;
-    rev = version;
-    sha256 = "sha256-JgGa7lomDvZG5HLxGJMALcezjnZprexJDTxyTUjLetg=";
-  };
-
-  preConfigure = ''
-    mkdir -p ${placeholder "out"}/share/cpm
-    cp ${cpm-cmake}/share/cpm/CPM.cmake ${placeholder "out"}/share/cpm/CPM_0.35.1.cmake
-  '';
-
-  cmakeFlags = [
-    "-DPOAC_BUILD_TESTING=OFF"
-    "-DCPM_SOURCE_CACHE=${placeholder "out"}/share"
-    "-DFETCHCONTENT_SOURCE_DIR_GIT2-CPP=${git2-cpp.src}"
-    "-DFETCHCONTENT_SOURCE_DIR_GLOB=${glob}"
-    "-DFETCHCONTENT_SOURCE_DIR_PACKAGEPROJECT.CMAKE=${package-project-cmake.src}"
-    "-DFETCHCONTENT_SOURCE_DIR_MITAMA-CPP-RESULT=${mitama-cpp-result.src}"
-    "-DFETCHCONTENT_SOURCE_DIR_NINJA=${ninja.src}"
-    "-DFETCHCONTENT_SOURCE_DIR_STRUCTOPT=${structopt}"
-    "-DFETCHCONTENT_SOURCE_DIR_TOML11=${toml11}"
-  ];
-
-  nativeBuildInputs = [ cmake git cacert ];
-  buildInputs = [
-    (boost179.override {
-      enableShared = stdenv.hostPlatform.isDarwin;
-      enableStatic = !stdenv.hostPlatform.isDarwin;
-    })
-    git2-cpp
-    glob
-    package-project-cmake
-    mitama-cpp-result
-    ninja
-    structopt
-    toml11
-    icu
-    libarchive
-    libgit2
-    lz4
-    openssl_3
-    spdlog
-  ];
-
-  meta = with lib; {
-    homepage = "https://poac.pm";
-    description = "Package Manager for C++";
-    license = licenses.asl20;
-    maintainers = [ ];
-    platforms = platforms.unix;
-    # error: call to 'format' is ambiguous
-    broken = true; # last successful build 2023-12-31
-  };
-}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 7e100e02c041..f709aea82df3 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5001,10 +5001,6 @@ with pkgs;
 
   po4a = perlPackages.Po4a;
 
-  poac = callPackage ../development/tools/poac {
-    inherit (llvmPackages_14) stdenv;
-  };
-
   podman-compose = python3Packages.callPackage ../applications/virtualization/podman-compose { };
 
   podman-desktop = callPackage ../applications/virtualization/podman-desktop {