From 63cc45e9eabd55ed60c65f2ebb51141ca6ecec23 Mon Sep 17 00:00:00 2001
From: Bazyli Cyran <bazyli@cyran.dev>
Date: Thu, 19 Sep 2024 18:15:54 +0200
Subject: [PATCH] git-smash: init at 0.1.1

---
 pkgs/by-name/gi/git-smash/package.nix | 51 +++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/gi/git-smash/package.nix

diff --git a/pkgs/by-name/gi/git-smash/package.nix b/pkgs/by-name/gi/git-smash/package.nix
new file mode 100644
index 000000000000..3d0be16148a6
--- /dev/null
+++ b/pkgs/by-name/gi/git-smash/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  installShellFiles,
+  makeWrapper,
+  fzf,
+  stdenv,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "git-smash";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "anthraxx";
+    repo = "git-smash";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-NyNYEF5g0O9xNhq+CoDPhQXZ+ISiY4DsShpjk5nP0N8=";
+  };
+
+  cargoHash = "sha256-omITZMBWzYlHHim/IXNa1rtiwHqpgLJ5G9z15YvDRi0=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    makeWrapper
+  ];
+
+  postFixup = ''
+    wrapProgram "$out/bin/git-smash" --suffix PATH : "${lib.makeBinPath [ fzf ]}"
+  '';
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd git-smash \
+      --bash <($out/bin/git-smash completions bash) \
+      --fish <($out/bin/git-smash completions fish) \
+      --zsh <($out/bin/git-smash completions zsh)
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Smash staged changes into previous commits to support your Git workflow, pull request and feature branch maintenance";
+    homepage = "https://github.com/anthraxx/git-smash";
+    changelog = "https://github.com/anthraxx/git-smash/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    mainProgram = "git-smash";
+    maintainers = with lib.maintainers; [ bcyran ];
+  };
+}