zeal: 0.6.1.20230320 -> 0.6.1.20230907

- Remove null defaults
- Use rec-less, overlay-style overridable recursive attributes (in effect since
https://github.com/NixOS/nixpkgs/pull/119942);
- Reorder lists
- Add myself to maintainers

pkgs/data/documentation/zeal/default.nix

@@ -7,7 +7,7 @@
 , qtbase
 , qtimageformats
 , qtwebengine
-, qtx11extras ? null # qt5 only
+, qtx11extras
 , libarchive
 , libXdmcp
 , libpthreadstubs
@@ -17,17 +17,16 @@
 
 let
   isQt5 = lib.versions.major qtbase.version == "5";
-
 in
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "zeal";
-  version = "0.6.1.20230320";
+  version = "0.6.1.20230907"; # unstable-date format not suitable for cmake
 
   src = fetchFromGitHub {
     owner = "zealdocs";
     repo = "zeal";
-    rev = "a617ae5e06b95cec99bae058650e55b98613916d";
-    hash = "sha256-WL2uqA0sZ5Q3lZIA9vkLVyfec/jBkfGcWb6XQ7AuM94=";
+    rev = "20249153077964d01c7c36b9f4042a40e8c8fbf1";
+    hash = "sha256-AyfpMq0R0ummTGvyUHOh/XBUeVfkFwo1VyyLSGoTN8w=";
   };
 
   # we only need this if we are using a version that hasn't been released. We
@@ -36,33 +35,40 @@ stdenv.mkDerivation rec {
   # line.
   postPatch = ''
     sed -i CMakeLists.txt \
-      -e 's@^project.*@project(Zeal VERSION ${version})@'
+      -e 's@^project.*@project(Zeal VERSION ${finalAttrs.version})@'
   '' + lib.optionalString (!isQt5) ''
     substituteInPlace src/app/CMakeLists.txt \
       --replace "COMPONENTS Widgets" "COMPONENTS Widgets QmlIntegration"
   '';
 
-  nativeBuildInputs = [ cmake extra-cmake-modules pkg-config wrapQtAppsHook ];
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    pkg-config
+    wrapQtAppsHook
+  ];
 
   buildInputs = [
+    libXdmcp
+    libarchive
+    libpthreadstubs
     qtbase
     qtimageformats
     qtwebengine
-    libarchive
-    libXdmcp
-    libpthreadstubs
     xcbutilkeysyms
-  ] ++ lib.optionals isQt5 [ qtx11extras ];
+  ]
+  ++ lib.optionals isQt5 [ qtx11extras ];
 
-  meta = with lib; {
+  meta = {
     description = "A simple offline API documentation browser";
     longDescription = ''
       Zeal is a simple offline API documentation browser inspired by Dash (macOS
       app), available for Linux and Windows.
     '';
     homepage = "https://zealdocs.org/";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ skeidel peterhoeg ];
-    platforms = platforms.linux;
+    changelog = "https://github.com/zealdocs/zeal/releases";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ skeidel peterhoeg AndersonTorres ];
+    inherit (qtbase.meta) platforms;
   };
-}
+})

pkgs/top-level/all-packages.nix

@@ -30409,8 +30409,10 @@ with pkgs;
   };
 
   zeal-qt5 = libsForQt5.callPackage ../data/documentation/zeal { };
-  zeal-qt6 = qt6Packages.callPackage ../data/documentation/zeal { };
   zeal = zeal-qt5;
+  zeal-qt6 = qt6Packages.callPackage ../data/documentation/zeal {
+    qtx11extras = null; # Because it does not exist in qt6
+  };
 
   zilla-slab = callPackage ../data/fonts/zilla-slab { };