Merge pull request #102928 from NeQuissimus/scala_test

scala: Add tests, update script

nixos/tests/all-tests.nix

@@ -314,6 +314,7 @@ in
   samba = handleTest ./samba.nix {};
   sanoid = handleTest ./sanoid.nix {};
   sbt = handleTest ./sbt.nix {};
+  scala = handleTest ./scala.nix {};
   sddm = handleTest ./sddm.nix {};
   service-runner = handleTest ./service-runner.nix {};
   shadowsocks = handleTest ./shadowsocks {};

nixos/tests/scala.nix

@@ -0,0 +1,33 @@
+{ system ? builtins.currentSystem,
+  config ? {},
+  pkgs ? import ../.. { inherit system config; }
+}:
+
+with pkgs.lib;
+
+let
+  common = name: package: (import ./make-test-python.nix ({
+    inherit name;
+    meta = with pkgs.stdenv.lib.maintainers; {
+      maintainers = [ nequissimus ];
+    };
+
+    nodes = {
+      scala = { ... }: {
+        environment.systemPackages = [ package ];
+      };
+    };
+
+    testScript = ''
+      start_all()
+
+      scala.succeed("scalac -version 2>&1 | grep '^Scala compiler version ${package.version}'")
+    '';
+  }) { inherit system; });
+
+in with pkgs; {
+  scala_2_10  = common "scala_2_10"  scala_2_10;
+  scala_2_11  = common "scala_2_11"  scala_2_11;
+  scala_2_12  = common "scala_2_12"  scala_2_12;
+  scala_2_13  = common "scala_2_13"  scala_2_13;
+}

pkgs/development/compilers/scala/2.10.nix

@@ -1,43 +0,0 @@
-{ stdenv, fetchurl, makeWrapper, jre, gnugrep, coreutils }:
-
-stdenv.mkDerivation rec {
-  name = "scala-2.10.7";
-
-  src = fetchurl {
-    url = "https://www.scala-lang.org/files/archive/${name}.tgz";
-    sha256 = "04gi55lzgrhsb78qw8jmnccqim92rw6898knw0a7gfzn2sci30wj";
-  };
-
-  propagatedBuildInputs = [ jre ] ;
-  buildInputs = [ makeWrapper ] ;
-
-  installPhase = ''
-    mkdir -p $out
-    rm bin/*.bat
-    mv * $out
-
-    for p in $(ls $out/bin/) ; do
-      wrapProgram $out/bin/$p \
-        --prefix PATH ":" ${coreutils}/bin \
-        --prefix PATH ":" ${gnugrep}/bin \
-        --prefix PATH ":" ${jre}/bin \
-        --set JAVA_HOME ${jre}
-    done
-  '';
-
-  meta = {
-    description = "A general purpose programming language";
-    longDescription = ''
-      Scala is a general purpose programming language designed to express
-      common programming patterns in a concise, elegant, and type-safe way.
-      It smoothly integrates features of object-oriented and functional
-      languages, enabling Java and other programmers to be more productive.
-      Code sizes are typically reduced by a factor of two to three when
-      compared to an equivalent Java application.
-    '';
-    homepage = "https://www.scala-lang.org/";
-    license = stdenv.lib.licenses.bsd3;
-    platforms = stdenv.lib.platforms.all;
-    branch = "2.10";
-  };
-}

pkgs/development/compilers/scala/2.11.nix

@@ -1,48 +0,0 @@
-{ stdenv, fetchurl, makeWrapper, jre, gnugrep, coreutils }:
-
-stdenv.mkDerivation rec {
-  name = "scala-2.11.12";
-
-  src = fetchurl {
-    url = "https://www.scala-lang.org/files/archive/${name}.tgz";
-    sha256 = "1a4nc4qp9dm4rps47j92hlmxxqskv67qbdmjqc5zd94wd4rps7di";
-  };
-
-  propagatedBuildInputs = [ jre ] ;
-  buildInputs = [ makeWrapper ] ;
-
-  installPhase = ''
-    mkdir -p $out
-    rm "bin/"*.bat
-    mv * $out
-
-    # put docs in correct subdirectory
-    mkdir -p $out/share/doc
-    mv $out/doc $out/share/doc/${name}
-    mv $out/man $out/share/man
-
-    for p in $(ls $out/bin/) ; do
-      wrapProgram $out/bin/$p \
-        --prefix PATH ":" ${coreutils}/bin \
-        --prefix PATH ":" ${gnugrep}/bin \
-        --prefix PATH ":" ${jre}/bin \
-        --set JAVA_HOME ${jre}
-    done
-  '';
-
-  meta = {
-    description = "General purpose programming language";
-    longDescription = ''
-      Scala is a general purpose programming language designed to express
-      common programming patterns in a concise, elegant, and type-safe way.
-      It smoothly integrates features of object-oriented and functional
-      languages, enabling Java and other programmers to be more productive.
-      Code sizes are typically reduced by a factor of two to three when
-      compared to an equivalent Java application.
-    '';
-    homepage = "https://www.scala-lang.org/";
-    license = stdenv.lib.licenses.bsd3;
-    platforms = stdenv.lib.platforms.all;
-    branch = "2.11";
-  };
-}

pkgs/development/compilers/scala/2.12.nix

@@ -1,47 +0,0 @@
-{ stdenv, fetchurl, makeWrapper, jre, gnugrep, coreutils }:
-
-stdenv.mkDerivation rec {
-  name = "scala-2.12.12";
-
-  src = fetchurl {
-    url = "https://www.scala-lang.org/files/archive/${name}.tgz";
-    sha256 = "0avyaa7y8w7494339krcpqhc2p8y5pjk4pz7mqmzdzwy7hgws81m";
-  };
-
-  propagatedBuildInputs = [ jre ] ;
-  buildInputs = [ makeWrapper ] ;
-
-  installPhase = ''
-    mkdir -p $out
-    rm "bin/"*.bat
-    mv * $out
-
-    # put docs in correct subdirectory
-    mkdir -p $out/share/doc
-    mv $out/doc $out/share/doc/scala
-    mv $out/{LICENSE,NOTICE} $out/share/doc/scala
-
-    for p in $(ls $out/bin/) ; do
-      wrapProgram $out/bin/$p \
-        --prefix PATH ":" ${coreutils}/bin \
-        --prefix PATH ":" ${gnugrep}/bin \
-        --prefix PATH ":" ${jre}/bin \
-        --set JAVA_HOME ${jre}
-    done
-  '';
-
-  meta = {
-    description = "General purpose programming language";
-    longDescription = ''
-      Scala is a general purpose programming language designed to express
-      common programming patterns in a concise, elegant, and type-safe way.
-      It smoothly integrates features of object-oriented and functional
-      languages, enabling Java and other programmers to be more productive.
-      Code sizes are typically reduced by a factor of two to three when
-      compared to an equivalent Java application.
-    '';
-    homepage = "https://www.scala-lang.org/";
-    license = stdenv.lib.licenses.bsd3;
-    platforms = stdenv.lib.platforms.all;
-  };
-}

pkgs/development/compilers/scala/2.13.nix

@@ -1,47 +0,0 @@
-{ stdenv, fetchurl, makeWrapper, jre, gnugrep, coreutils }:
-
-stdenv.mkDerivation rec {
-  name = "scala-2.13.3";
-
-  src = fetchurl {
-    url = "https://www.scala-lang.org/files/archive/${name}.tgz";
-    sha256 = "0zv9w9f6g2cfydsvp8mqcfgv2v3487xp4ca1qndg6v7jrhdp7wy9";
-  };
-
-  propagatedBuildInputs = [ jre ] ;
-  buildInputs = [ makeWrapper ] ;
-
-  installPhase = ''
-    mkdir -p $out
-    rm "bin/"*.bat
-    mv * $out
-
-    # put docs in correct subdirectory
-    mkdir -p $out/share/doc
-    mv $out/doc $out/share/doc/scala
-    mv $out/{LICENSE,NOTICE} $out/share/doc/scala
-
-    for p in $(ls $out/bin/) ; do
-      wrapProgram $out/bin/$p \
-        --prefix PATH ":" ${coreutils}/bin \
-        --prefix PATH ":" ${gnugrep}/bin \
-        --prefix PATH ":" ${jre}/bin \
-        --set JAVA_HOME ${jre}
-    done
-  '';
-
-  meta = {
-    description = "General purpose programming language";
-    longDescription = ''
-      Scala is a general purpose programming language designed to express
-      common programming patterns in a concise, elegant, and type-safe way.
-      It smoothly integrates features of object-oriented and functional
-      languages, enabling Java and other programmers to be more productive.
-      Code sizes are typically reduced by a factor of two to three when
-      compared to an equivalent Java application.
-    '';
-    homepage = "https://www.scala-lang.org/";
-    license = stdenv.lib.licenses.bsd3;
-    platforms = stdenv.lib.platforms.all;
-  };
-}

pkgs/development/compilers/scala/2.x.nix

@@ -0,0 +1,117 @@
+{ stdenv, lib, fetchurl, makeWrapper, jre, gnugrep, coreutils, nixosTests
+, writeScript, common-updater-scripts, git, gnused, nix, nixfmt }:
+
+with lib;
+
+let
+  repo = "git@github.com:scala/scala.git";
+
+  common = { version, sha256, test, pname }:
+    stdenv.mkDerivation rec {
+      inherit version;
+
+      name = "scala-${version}";
+
+      src = fetchurl {
+        inherit sha256;
+        url = "https://www.scala-lang.org/files/archive/scala-${version}.tgz";
+      };
+
+      propagatedBuildInputs = [ jre ];
+      buildInputs = [ makeWrapper ];
+
+      installPhase = ''
+        mkdir -p $out
+        rm bin/*.bat
+        mv * $out
+
+        # put docs in correct subdirectory
+        mkdir -p $out/share/doc
+        mv $out/doc $out/share/doc/${name}
+        mv $out/man $out/share/man
+
+        for p in $(ls $out/bin/) ; do
+          wrapProgram $out/bin/$p \
+            --prefix PATH ":" ${coreutils}/bin \
+            --prefix PATH ":" ${gnugrep}/bin \
+            --prefix PATH ":" ${jre}/bin \
+            --set JAVA_HOME ${jre}
+        done
+      '';
+
+      passthru = {
+        tests = [ test ];
+
+        updateScript = writeScript "update.sh" ''
+          #!${stdenv.shell}
+          set -o errexit
+          PATH=${
+            stdenv.lib.makeBinPath [
+              common-updater-scripts
+              coreutils
+              git
+              gnused
+              nix
+              nixfmt
+            ]
+          }
+          versionSelect='v${versions.major version}.${versions.minor version}.*'
+          oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion ${pname}" | tr -d '"')"
+          latestTag="$(git -c 'versionsort.suffix=-' ls-remote --exit-code --refs --sort='version:refname' --tags ${repo} "$versionSelect" | tail --lines=1 | cut --delimiter='/' --fields=3 | sed 's|^v||g')"
+          if [ "$oldVersion" != "$latestTag" ]; then
+            nixpkgs="$(git rev-parse --show-toplevel)"
+            default_nix="$nixpkgs/pkgs/development/compilers/scala/2.x.nix"
+            update-source-version ${pname} "$latestTag" --version-key=version --print-changes
+            nixfmt "$default_nix"
+          else
+            echo "${pname} is already up-to-date"
+          fi
+        '';
+      };
+
+      meta = {
+        description = "A general purpose programming language";
+        longDescription = ''
+          Scala is a general purpose programming language designed to express
+          common programming patterns in a concise, elegant, and type-safe way.
+          It smoothly integrates features of object-oriented and functional
+          languages, enabling Java and other programmers to be more productive.
+          Code sizes are typically reduced by a factor of two to three when
+          compared to an equivalent Java application.
+        '';
+        homepage = "https://www.scala-lang.org/";
+        license = licenses.bsd3;
+        platforms = platforms.all;
+        branch = versions.majorMinor version;
+        maintainers = [ maintainers.nequissimus ];
+      };
+    };
+in {
+  scala_2_10 = common {
+    version = "2.10.7";
+    sha256 = "koMRmRb2u3cU4HaihAzPItWIGbNVIo7RWRrm92kp8RE=";
+    test = { inherit (nixosTests) scala_2_10; };
+    pname = "scala_2_10";
+  };
+
+  scala_2_11 = common {
+    version = "2.11.12";
+    sha256 = "sR19M2mcpPYLw7K2hY/ZU+PeK4UiyUP0zaS2dDFhlqg=";
+    test = { inherit (nixosTests) scala_2_11; };
+    pname = "scala_2_11";
+  };
+
+  scala_2_12 = common {
+    version = "2.12.12";
+    sha256 = "NSDNHzye//YrrudfMuUtHl3BIL4szzQGSeRw5I9Sfis=";
+    test = { inherit (nixosTests) scala_2_12; };
+    pname = "scala_2_12";
+  };
+
+  scala_2_13 = common {
+    version = "2.13.3";
+    sha256 = "yfNzG8zybPOaxUExcvtBZGyxn2O4ort1846JZ1ziaX8=";
+    test = { inherit (nixosTests) scala_2_13; };
+    pname = "scala_2_13";
+  };
+}

pkgs/top-level/all-packages.nix

@@ -9931,10 +9931,12 @@ in
   sbcl_2_0_9 = callPackage ../development/compilers/sbcl/2.0.9.nix {};
   sbcl = callPackage ../development/compilers/sbcl {};
 
-  scala_2_10 = callPackage ../development/compilers/scala/2.10.nix { };
-  scala_2_11 = callPackage ../development/compilers/scala/2.11.nix { };
-  scala_2_12 = callPackage ../development/compilers/scala/2.12.nix { jre = jre8; };
-  scala_2_13 = callPackage ../development/compilers/scala/2.13.nix { jre = jre8; };
+  inherit (callPackage ../development/compilers/scala/2.x.nix { jre = jre8; })
+    scala_2_10
+    scala_2_11
+    scala_2_12
+    scala_2_13;
+
   scala = scala_2_13;
 
   metal = callPackage ../development/libraries/metal { };