From 516ca7d8a332ae784d0f4c06d460aa61dd11b463 Mon Sep 17 00:00:00 2001
From: zendo <linzway@qq.com>
Date: Tue, 28 Mar 2023 18:56:06 +0800
Subject: [PATCH] notes: init at 2.2.0

---
 pkgs/applications/office/notes/default.nix | 54 ++++++++++++++++++++++
 pkgs/top-level/all-packages.nix            |  4 ++
 2 files changed, 58 insertions(+)
 create mode 100644 pkgs/applications/office/notes/default.nix

diff --git a/pkgs/applications/office/notes/default.nix b/pkgs/applications/office/notes/default.nix
new file mode 100644
index 000000000000..7ddc7d98dda7
--- /dev/null
+++ b/pkgs/applications/office/notes/default.nix
@@ -0,0 +1,54 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, wrapQtAppsHook
+, qtbase
+, qtdeclarative
+, Cocoa
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "notes";
+  version = "2.2.0";
+
+  src = fetchFromGitHub {
+    owner = "nuttyartist";
+    repo = "notes";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-ZfAm77UHyjs2aYOYb+AhKViz6uteb7+KKSedonSiMkY=";
+    fetchSubmodules = true;
+  };
+
+  cmakeFlags = [ "-DUPDATE_CHECKER=OFF" ];
+
+  nativeBuildInputs = [
+    cmake
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    qtbase
+    qtdeclarative
+  ] ++ lib.optionals stdenv.isDarwin [
+    Cocoa
+  ];
+
+  postInstall = lib.optionalString stdenv.isLinux ''
+    # temporary fix: https://github.com/nuttyartist/notes/issues/613
+    substituteInPlace $out/share/applications/io.github.nuttyartist.notes.desktop \
+       --replace 'Exec=notes' 'Exec=env QT_STYLE_OVERRIDE= notes'
+  '' + lib.optionalString stdenv.isDarwin ''
+    mkdir $out/Applications
+    mv $out/bin/Notes.app $out/Applications
+  '';
+
+  meta = {
+    description = "A fast and beautiful note-taking app";
+    downloadPage = "https://github.com/nuttyartist/notes";
+    homepage = "https://www.get-notes.com";
+    license = lib.licenses.mpl20;
+    maintainers = with lib.maintainers; [ zendo ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f4829aa9227a..7f730dc0ccf3 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -10392,6 +10392,10 @@ with pkgs;
 
   notify-osd = callPackage ../applications/misc/notify-osd { };
 
+  notes = qt6Packages.callPackage ../applications/office/notes {
+    inherit (darwin.apple_sdk.frameworks) Cocoa;
+  };
+
   notes-up = callPackage ../applications/office/notes-up { };
 
   notify-osd-customizable = callPackage ../applications/misc/notify-osd-customizable { };