From 36a1b0dc58094b912b094f307b1cb98e73419d2e Mon Sep 17 00:00:00 2001
From: Gavin John <gavinnjohn@gmail.com>
Date: Tue, 9 Jul 2024 11:32:03 -0400
Subject: [PATCH] nixos/qgroundcontrol: init module

---
 nixos/modules/module-list.nix             |  1 +
 nixos/modules/programs/qgroundcontrol.nix | 53 +++++++++++++++++++++++
 2 files changed, 54 insertions(+)
 create mode 100644 nixos/modules/programs/qgroundcontrol.nix

diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index fc62e9db1785..5b8be7a969ba 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -258,6 +258,7 @@
   ./programs/projecteur.nix
   ./programs/proxychains.nix
   ./programs/qdmr.nix
+  ./programs/qgroundcontrol.nix
   ./programs/qt5ct.nix
   ./programs/quark-goldleaf.nix
   ./programs/regreet.nix
diff --git a/nixos/modules/programs/qgroundcontrol.nix b/nixos/modules/programs/qgroundcontrol.nix
new file mode 100644
index 000000000000..bf949279dbae
--- /dev/null
+++ b/nixos/modules/programs/qgroundcontrol.nix
@@ -0,0 +1,53 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.programs.qgroundcontrol;
+in
+{
+
+  options = {
+    programs.qgroundcontrol = {
+      enable = lib.mkEnableOption "qgroundcontrol";
+
+      package = lib.mkPackageOption pkgs "qgroundcontrol" {};
+
+      blacklistModemManagerFromTTYUSB = lib.mkOption {
+        type = lib.types.bool;
+        default = true;
+        description = ''
+          Disallow ModemManager from interfering with serial connections that QGroundControl might use.
+
+          Note that if you use a modem that's connected via USB, you might want to disable this option.
+        '';
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    # ModemManager is known to interfere with serial connections;
+    # QGC recommends disabling it, but we don't want to if we can avoid it
+    # Instead, we blacklist tty devices using udev rules, which is a more targeted approach
+    services.udev = lib.mkIf cfg.blacklistModemManagerFromTTYUSB {
+      enable = true;
+      extraRules = ''
+        # nixos/qgroundcontrol: Blacklist ttyUSB devices from ModemManager
+        SUBSYSTEM=="tty", KERNEL=="ttyUSB*", ENV{ID_MM_DEVICE_IGNORE}="1"
+      '';
+    };
+
+    # Security wrapper
+    security.wrappers.qgroundcontrol = {
+      source = lib.getExe cfg.package;
+      owner = "root"; # Sensible default; not setuid so this is not a security risk
+      group = "tty";
+      setgid = true;
+    };
+  };
+
+  meta.maintainers = pkgs.qgroundcontrol.meta.maintainers ++ (with lib.maintainers; [ pandapip1 ]);
+}