tworld2: init at 2.2.0

pkgs/games/tworld2/default.nix

@@ -0,0 +1,45 @@
+{ stdenv
+, lib
+, fetchurl
+, qt4
+, SDL
+}:
+
+stdenv.mkDerivation rec {
+  pname = "tworld2";
+  version = "2.2.0";
+
+  src = fetchurl {
+    url = "https://tw2.bitbusters.club/downloads/tworld-${version}-src.tar.gz";
+    sha256 = "sha256:1y55v2shk2xxcds7bdwdjaq9lka31sgdp2469zqnvldchwbvcb2i";
+  };
+
+  buildInputs = [ qt4 SDL ];
+  enableParallelBuilding = true;
+
+  postConfigure = ''
+    echo "#define COMPILE_TIME \"$(date -ud "@$SOURCE_DATE_EPOCH" '+%Y %b %e %T %Z')\"" >comptime.h
+  '';
+
+  makeFlags = [
+    "bindir=${placeholder "out"}/bin"
+    "sharedir=${placeholder "out"}/share"
+    "mandir=${placeholder "out"}/share/man/en"
+  ];
+
+  postInstall = ''
+    mkdir -p $out/share/doc/${pname}
+    cp COPYING README docs/tworld2.html $out/share/doc/${pname}
+
+    mkdir $out/share/icons
+    cp tworld.ico tworld2.ico $out/share/icons
+  '';
+
+  meta = with lib; {
+    description = "Tile World 2: Tile World is a reimplementation of the game Chip's Challenge";
+    homepage = "https://tw2.bitbusters.club/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ drperceptron ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -31061,6 +31061,8 @@ with pkgs;
 
   tuxtype = callPackage ../games/tuxtype { };
 
+  tworld2 = callPackage ../games/tworld2 { };
+
   speed_dreams = callPackage ../games/speed-dreams {
     # Torcs wants to make shared libraries linked with plib libraries (it provides static).
     # i686 is the only platform I know than can do that linking without plib built with -fPIC