From c4be0fbe51257d5027e52ed5258922afab2c37ae Mon Sep 17 00:00:00 2001
From: kilianar <mail@kilianar.de>
Date: Tue, 10 Sep 2024 14:08:43 +0200
Subject: [PATCH] wealthfolio: init at 1.0.18

https://github.com/afadil/wealthfolio/releases/tag/v1.0.18
---
 pkgs/by-name/we/wealthfolio/package.nix | 64 +++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 pkgs/by-name/we/wealthfolio/package.nix

diff --git a/pkgs/by-name/we/wealthfolio/package.nix b/pkgs/by-name/we/wealthfolio/package.nix
new file mode 100644
index 000000000000..6c9b99348071
--- /dev/null
+++ b/pkgs/by-name/we/wealthfolio/package.nix
@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cargo-tauri,
+  libsoup,
+  nodejs,
+  openssl,
+  pkg-config,
+  pnpm,
+  rustPlatform,
+  webkitgtk_4_0,
+  wrapGAppsHook3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wealthfolio";
+  version = "1.0.18";
+
+  src = fetchFromGitHub {
+    owner = "afadil";
+    repo = "wealthfolio";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-AH0bwzsnGaGE82Ds1pDeZkVY2GXEB7RqHYw+WAt69/4=";
+  };
+
+  pnpmDeps = pnpm.fetchDeps {
+    inherit (finalAttrs) src pname version;
+    hash = "sha256-OpQg/ZZ4M2vszMZeCJAKzqGduxexZfIVe3Jy/hG3Yu0=";
+  };
+
+  cargoRoot = "src-tauri";
+  buildAndTestSubdir = finalAttrs.cargoRoot;
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit (finalAttrs) pname version src;
+    sourceRoot = "${finalAttrs.src.name}/${finalAttrs.cargoRoot}";
+    hash = "sha256-jbdshb+Kjnh/yKQlCVaYT3/RQ6Zyo2dm72EToLsbqxc=";
+  };
+
+  nativeBuildInputs = [
+    cargo-tauri.hook
+    nodejs
+    pkg-config
+    pnpm.configHook
+    rustPlatform.cargoSetupHook
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    libsoup
+    openssl
+    webkitgtk_4_0
+  ];
+
+  meta = {
+    description = "A Beautiful Private and Secure Desktop Investment Tracking Application";
+    homepage = "https://wealthfolio.app/";
+    license = lib.licenses.agpl3Only;
+    mainProgram = "wealthfolio";
+    maintainers = with lib.maintainers; [ kilianar ];
+    platforms = lib.platforms.linux;
+  };
+})