Merge pull request #203687 from stehessel/rhoas/init-0.51.7

pkgs/tools/admin/rhoas/default.nix

@@ -0,0 +1,46 @@
+{ lib, buildGoModule, fetchFromGitHub, installShellFiles, testers, rhoas }:
+
+buildGoModule rec {
+  pname = "rhoas";
+  version = "0.51.7";
+
+  src = fetchFromGitHub {
+    owner = "redhat-developer";
+    repo = "app-services-cli";
+    rev = "v${version}";
+    sha256 = "sha256-sgAr9v3nkMZ8linvR5AhYZV0NQuVqMnueGOo/KLqPc0=";
+  };
+
+  vendorSha256 = null;
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/redhat-developer/app-services-cli/internal/build.Version=${version}"
+  ];
+
+  nativeBuildInputs = [installShellFiles];
+
+  # Networking tests fail.
+  doCheck = false;
+
+  postInstall = ''
+    installShellCompletion --cmd rhoas \
+      --bash <($out/bin/rhoas completion bash) \
+      --fish <($out/bin/rhoas completion fish) \
+      --zsh <($out/bin/rhoas completion zsh)
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = rhoas;
+    command = "HOME=$TMP rhoas version";
+  };
+
+  meta = with lib; {
+    description = "Command Line Interface for Red Hat OpenShift Application Services";
+    license = licenses.asl20;
+    homepage = "https://github.com/redhat-developer/app-services-cli";
+    changelog = "https://github.com/redhat-developer/app-services-cli/releases/v${version}";
+    maintainers = with maintainers; [stehessel];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -11249,6 +11249,8 @@ with pkgs;
 
   rhash = callPackage ../tools/security/rhash { };
 
+  rhoas = callPackage ../tools/admin/rhoas { };
+
   riemann_c_client = callPackage ../tools/misc/riemann-c-client { };
   riemann-tools = callPackage ../tools/misc/riemann-tools { };