flent: 2.1.1 -> 2.2.0

pkgs/by-name/fl/flent/package.nix

@@ -1,55 +1,66 @@
 {
   lib,
-  buildPythonApplication,
+  python3Packages,
   fetchPypi,
   procps,
-  python,
   qt5,
   xvfb-run,
 }:
-buildPythonApplication rec {
+python3Packages.buildPythonApplication rec {
   pname = "flent";
-  version = "2.1.1";
+  version = "2.2.0";
+
   src = fetchPypi {
     inherit pname version;
-    hash = "sha256-21gd6sPYCZll3Q2O7kucTRhXvc5byXeQr50+1bZVT3M=";
+    hash = "sha256-BPwh3oWIY1YEI+ecgi9AUiX4Ka/Y5dYikwmfvvNB+eg=";
   };
 
-  buildInputs = [ python.pkgs.sphinx ];
+  build-system = [ python3Packages.sphinx ];
+
   nativeBuildInputs = [ qt5.wrapQtAppsHook ];
-  propagatedBuildInputs = [
-    procps
-    python.pkgs.matplotlib
-    python.pkgs.pyqt5
-    python.pkgs.qtpy
+
+  dependencies = with python3Packages; [
+    matplotlib
+    pyqt5
+    qtpy
   ];
+
   nativeCheckInputs = [
-    python.pkgs.mock
+    python3Packages.mock
     xvfb-run
   ];
 
   checkPhase = ''
+    runHook preCheck
+
     # we want the gui tests to always run
     sed -i 's|self.skip|pass; #&|' unittests/test_gui.py
 
+    export XDG_RUNTIME_DIR=$(mktemp -d)
+    export HOME=$(mktemp -d)
     cat >test-runner <<EOF
     #!/bin/sh
-    ${python.pythonOnBuildForHost.interpreter} nix_run_setup test
+    ${python3Packages.python.interpreter} -m unittest discover
     EOF
     chmod +x test-runner
     wrapQtApp test-runner --prefix PYTHONPATH : $PYTHONPATH
     xvfb-run -s '-screen 0 800x600x24' ./test-runner
+
+    runHook postCheck
   '';
 
   preFixup = ''
-    makeWrapperArgs+=("''${qtWrapperArgs[@]}")
+    makeWrapperArgs+=(
+      "''${qtWrapperArgs[@]}"
+      --prefix PATH : ${lib.makeBinPath [ procps ]}
+    )
   '';
 
-  meta = with lib; {
+  meta = {
     description = "FLExible Network Tester";
     homepage = "https://flent.org";
-    license = licenses.gpl3;
-
-    maintainers = [ maintainers.mmlb ];
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ mmlb ];
+    mainProgram = "flent";
   };
 }