isponsorblocktv: init at 2.2.1 (#343585)

pkgs/by-name/is/isponsorblocktv/package.nix

@@ -0,0 +1 @@
+{ python3Packages }: python3Packages.callPackage ./pypackage.nix { }

pkgs/by-name/is/isponsorblocktv/pypackage.nix

@@ -0,0 +1,69 @@
+{
+  buildPythonApplication,
+  fetchFromGitHub,
+  lib,
+  hatchling,
+  hatch-requirements-txt,
+  aiohttp,
+  appdirs,
+  async-cache,
+  pyytlounge,
+  rich-click,
+  rich,
+  ssdp,
+  textual-slider,
+  textual,
+  xmltodict,
+  pythonRelaxDepsHook,
+}:
+buildPythonApplication rec {
+  pname = "iSponsorBlockTV";
+  version = "2.2.1";
+
+  src = fetchFromGitHub {
+    owner = "dmunozv04";
+    repo = "iSponsorBlockTV";
+    rev = "v${version}";
+    hash = "sha256-v5NF6o+9IxusYNebs2a9fgHCHZNN9hHLQurujhmdsgU=";
+  };
+
+  pyproject = true;
+
+  build-system = [
+    hatchling
+    hatch-requirements-txt
+  ];
+
+  dependencies = [
+    aiohttp
+    appdirs
+    async-cache
+    pyytlounge
+    rich-click
+    rich
+    ssdp
+    textual-slider
+    textual
+    xmltodict
+  ];
+
+  nativeBuildInputs = [ pythonRelaxDepsHook ];
+
+  pythonRemoveDeps = [ "argparse" ];
+
+  pythonRelaxDeps = [
+    "aiohttp"
+    "pyytlounge"
+    "textual-slider"
+    "textual"
+  ];
+
+  meta = {
+    homepage = "https://github.com/dmunozv04/iSponsorBlockTV";
+    description = "SponsorBlock client for all YouTube TV clients";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ lukegb ];
+    mainProgram = "iSponsorBlockTV";
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/development/python-modules/async-cache/default.nix

@@ -0,0 +1,24 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+}:
+
+buildPythonPackage rec {
+  pname = "async-cache";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "iamsinghrajat";
+    repo = "async-cache";
+    rev = "9925f07920e6b585dc6345f49b7f477b3e1b8c2c"; # doesn't tag releases :(
+    hash = "sha256-AVSdtWPs1c8AE5PNOq+BdXzBXkI0aeFVzxxPl/ATyU0=";
+  };
+
+  meta = with lib; {
+    description = "Caching solution for asyncio";
+    homepage = "https://github.com/iamsinghrajat/async-cache";
+    license = licenses.mit;
+    maintainers = [ maintainers.lukegb ];
+  };
+}

pkgs/development/python-modules/pyytlounge/default.nix

@@ -0,0 +1,45 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  hatchling,
+  aiohttp,
+  pytest,
+  pytestCheckHook,
+  pytest-mock,
+  pytest-asyncio,
+}:
+
+buildPythonPackage rec {
+  pname = "pyytlounge";
+  version = "2.1.1";
+
+  src = fetchFromGitHub {
+    owner = "FabioGNR";
+    repo = "pyytlounge";
+    rev = "v${version}";
+    hash = "sha256-0QPa3EzOBv5fuw3FGgmoN4KiC4KHo1Z+Svjcneoe0pc=";
+  };
+
+  pyproject = true;
+
+  doCheck = true;
+
+  build-system = [ hatchling ];
+
+  dependencies = [ aiohttp ];
+
+  nativeCheckInputs = [
+    pytest
+    pytestCheckHook
+    pytest-mock
+    pytest-asyncio
+  ];
+
+  meta = with lib; {
+    description = "Python YouTube Lounge API";
+    homepage = "https://github.com/FabioGNR/pyytlounge";
+    license = licenses.gpl3Only;
+    maintainers = [ maintainers.lukegb ];
+  };
+}

pkgs/development/python-modules/textual-slider/default.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  textual,
+}:
+
+buildPythonPackage rec {
+  pname = "textual-slider";
+  version = "0.1.2";
+
+  src = fetchFromGitHub {
+    owner = "TomJGooding";
+    repo = "textual-slider";
+    rev = "91e64bafe3aa72f8d875e76b437d6af9320e039e";
+    hash = "sha256-lwN7igiEB8uC9e7qBSVLuKCpF41+Ni7ZJ3cVK19cEY8=";
+  };
+
+  pyproject = true;
+
+  build-system = [ setuptools ];
+
+  dependencies = [ textual ];
+
+  meta = with lib; {
+    description = "Textual widget for a simple slider";
+    homepage = "https://github.com/TomJGooding/textual-slider";
+    license = licenses.gpl3Only;
+    maintainers = [ maintainers.lukegb ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -902,6 +902,8 @@ self: super: with self; {
 
   asyncarve = callPackage ../development/python-modules/asyncarve { };
 
+  async-cache = callPackage ../development/python-modules/async-cache { };
+
   async-dns = callPackage ../development/python-modules/async-dns { };
 
   async-generator = callPackage ../development/python-modules/async-generator { };
@@ -13147,6 +13149,8 @@ self: super: with self; {
 
   pyyardian = callPackage ../development/python-modules/pyyardian { };
 
+  pyytlounge = callPackage ../development/python-modules/pyytlounge { };
+
   pyzabbix = callPackage ../development/python-modules/pyzabbix { };
 
   pyzerproc = callPackage ../development/python-modules/pyzerproc { };
@@ -15433,6 +15437,8 @@ self: super: with self; {
 
   textual-dev = callPackage ../development/python-modules/textual-dev { };
 
+  textual-slider = callPackage ../development/python-modules/textual-slider { };
+
   textual-universal-directorytree = callPackage ../development/python-modules/textual-universal-directorytree { };
 
   testbook = callPackage ../development/python-modules/testbook { };