Merge pull request #272993 from EwuUwe/gnome-resources

gnome-resources: init at 1.2.1

maintainers/maintainer-list.nix

@@ -5676,6 +5676,12 @@
     githubId = 454695;
     name = "Artur Taranchiev";
   };
+  ewuuwe = {
+    email = "ewu.uweq@pm.me";
+    github = "ewuuwe";
+    githubId = 63652646;
+    name = "Xaver Oswald";
+  };
   exarkun = {
     email = "exarkun@twistedmatrix.com";
     github = "exarkun";

pkgs/tools/system/gnome-resources/default.nix

@@ -0,0 +1,71 @@
+{ fetchFromGitHub
+, stdenv
+, lib
+, appstream-glib
+, cargo
+, desktop-file-utils
+, meson
+, pkg-config
+, rustPlatform
+, rustc
+, glib
+, wrapGAppsHook4
+, systemd
+, polkit
+, dmidecode
+, gtk4
+, libadwaita
+, ninja
+}:
+stdenv.mkDerivation rec {
+  pname = "gnome-resources";
+  version = "1.2.1";
+
+  src = fetchFromGitHub {
+    owner = "nokyan";
+    repo = "resources";
+    rev = "v${version}";
+    hash = "sha256-OVz1vsmOtH/5sEuyl2BfDqG2/9D1HGtHA0FtPntKQT0=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit src;
+    hash = "sha256-SkCEA9CKqzy0wSIUj0DG6asIysD7G9i3nJ9jwhwAUqY=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    desktop-file-utils
+    appstream-glib
+    meson
+    ninja
+    rustc
+    cargo
+    rustPlatform.cargoSetupHook
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    glib
+    gtk4
+    libadwaita
+    polkit
+    systemd
+  ];
+
+  postPatch = ''
+    substituteInPlace src/utils/memory.rs \
+      --replace '"dmidecode"' '"${dmidecode}/bin/dmidecode"'
+  '';
+
+  mesonFlags = [ "-Dprofile=default" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/nokyan/resources";
+    description = "Monitor your system resources and processes";
+    license = licenses.gpl3Plus;
+    mainProgram = "resources";
+    maintainers = with maintainers; [ ewuuwe ];
+    platforms = platforms.linux;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -8673,6 +8673,8 @@ with pkgs;
 
   gnome-randr = callPackage ../tools/wayland/gnome-randr { };
 
+  gnome-resources = callPackage ../tools/system/gnome-resources { };
+
   gnuapl = callPackage ../development/interpreters/gnu-apl { };
 
   gnu-shepherd = callPackage ../misc/gnu-shepherd { };