tiddit: init at 3.6.1

Genomic tool to call structural variations.

This packages requires 2 executables,packaging fermi2, bwt2, that are
packaged in the same derivation and added to the path later on.

pkgs/by-name/ro/ropebwt2/package.nix

@@ -17,13 +17,15 @@ stdenv.mkDerivation {
   makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
   installPhase = ''
     runHook preInstall
+
     install -Dm755 ropebwt2 -t $out/bin
+
     runHook postInstall
   '';
   meta = {
     homepage = "https://github.com/lh3/ropebwt2";
     description = "Incremental construction of FM-index for DNA sequences";
-    mainProgram = "ropebwwith lib; t2";
+    mainProgram = "ropebwt2";
     license = lib.licenses.mit;
     maintainers = with lib.maintainers; [ apraga ];
     platforms = lib.platforms.unix;

pkgs/by-name/ti/tiddit/package.nix

@@ -0,0 +1,51 @@
+{
+  bwa,
+  lib,
+  fermi2,
+  ropebwt2,
+  fetchFromGitHub,
+  python3Packages,
+}:
+python3Packages.buildPythonApplication rec {
+  name = "tiddit";
+  version = "3.6.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "SciLifeLab";
+    repo = "TIDDIT";
+    rev = "refs/tags/TIDDIT-${version}";
+    hash = "sha256-OeqVQJDw0fmSDWIGab2qtTJCzZxqLY2XzRqaTRuPIdI=";
+  };
+
+  build-system = with python3Packages; [
+    setuptools
+    wheel
+  ];
+
+  dependencies = with python3Packages; [
+    cython
+    joblib
+    numpy
+    pysam
+  ];
+
+  makeWrapperArgs = [
+    "--prefix PATH : ${
+      lib.makeBinPath [
+        bwa
+        fermi2
+        ropebwt2
+      ]
+    }"
+  ];
+
+  meta = {
+    homepage = "https://github.com/SciLifeLab/TIDDIT";
+    description = "Identify chromosomal rearrangements using Mate Pair or Paired End sequencing data";
+    mainProgram = "tiddit";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ apraga ];
+    platforms = lib.platforms.unix;
+  };
+}