From 181bfe85f3a12bde080e1f0bd922c3d2d3a48230 Mon Sep 17 00:00:00 2001
From: jopejoe1 <johannes@joens.email>
Date: Sun, 3 Nov 2024 17:05:57 +0100
Subject: [PATCH] alac: init at 0.0.7-unstable-2024-10-16

(cherry picked from commit 5e09c0ef0d10b1ad77fed18faad8470d757b3869)
---
 pkgs/by-name/al/alac/package.nix | 45 ++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 pkgs/by-name/al/alac/package.nix

diff --git a/pkgs/by-name/al/alac/package.nix b/pkgs/by-name/al/alac/package.nix
new file mode 100644
index 000000000000..5aaedfe3c454
--- /dev/null
+++ b/pkgs/by-name/al/alac/package.nix
@@ -0,0 +1,45 @@
+{
+  autoreconfHook,
+  fetchFromGitHub,
+  lib,
+  stdenv,
+  testers,
+  unstableGitUpdater,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "alac";
+  version = "0.0.7-unstable-2024-10-16";
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "mikebrady";
+    repo = "alac";
+    rev = "1832544d27d01335d823d639b176d1cae25ecfd4";
+    hash = "sha256-xRWDeqyJ/BEaSWVlDXgaKIKJuBwM8kJDIATVTVaMn2k=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+  ];
+
+  # error: 'TARGET_OS_MAC' is not defined, evaluates to 0
+  env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isDarwin "-DTARGET_OS_MAC";
+
+  passthru = {
+    updateScript = unstableGitUpdater { };
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "Apple Lossless Codec and Utility with Autotools";
+    homepage = "https://github.com/mikebrady/alac";
+    license = lib.licenses.asl20;
+    pkgConfigModules = [ "alac" ];
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ jopejoe1 ];
+  };
+})