diff --git a/pkgs/by-name/co/concurrently/package.nix b/pkgs/by-name/co/concurrently/package.nix
new file mode 100644
index 000000000000..c53adc26c610
--- /dev/null
+++ b/pkgs/by-name/co/concurrently/package.nix
@@ -0,0 +1,77 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch2,
+  makeWrapper,
+  nodejs,
+  pnpm_8,
+}:
+
+let
+  pnpm = pnpm_8;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "concurrently";
+  version = "8.2.2";
+
+  src = fetchFromGitHub {
+    owner = "open-cli-tools";
+    repo = "concurrently";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-VoyVYBOBMguFKnG2VItk1L5BbF72nO7bYJpb7adqICs=";
+  };
+
+  pnpmDeps = pnpm.fetchDeps {
+    inherit (finalAttrs)
+      pname
+      version
+      src
+      patches
+      ;
+    hash = "sha256-F1teWIABkK0mqZcK3RdGNKmexI/C59QWSrrD1jYbHt0=";
+  };
+
+  patches = [
+    (fetchpatch2 {
+      name = "use-pnpm-8.patch";
+      url = "https://github.com/open-cli-tools/concurrently/commit/0b67a1a5a335396340f4347886fb9d0968a57555.patch";
+      hash = "sha256-mxid2Yl9S6+mpN7OLUCrJ1vS0bQ/UwNiGJ0DL6Zn//Q=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    makeWrapper
+    nodejs
+    pnpm.configHook
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/bin" "$out/lib/concurrently"
+    cp -r dist node_modules "$out/lib/concurrently"
+    makeWrapper "${lib.getExe nodejs}" "$out/bin/concurrently" \
+      --add-flags "$out/lib/concurrently/dist/bin/concurrently.js"
+    ln -s "$out/bin/concurrently" "$out/bin/con"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    changelog = "https://github.com/open-cli-tools/concurrently/releases/tag/v${finalAttrs.version}";
+    description = "Run commands concurrently";
+    homepage = "https://github.com/open-cli-tools/concurrently";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ jpetrucciani ];
+    mainProgram = "concurrently";
+  };
+})
diff --git a/pkgs/development/node-packages/aliases.nix b/pkgs/development/node-packages/aliases.nix
index 5bbe69039d84..db222ade4921 100644
--- a/pkgs/development/node-packages/aliases.nix
+++ b/pkgs/development/node-packages/aliases.nix
@@ -72,6 +72,7 @@ mapAliases {
   coc-imselect = throw "coc-imselect was removed because it was broken"; # added 2023-08-21
   coinmon = throw "coinmon was removed since it was abandoned upstream"; # added 2024-03-19
   coffee-script = pkgs.coffeescript; # added 2023-08-18
+  inherit (pkgs) concurrently; # added 2024-08-05
   inherit (pkgs) configurable-http-proxy; # added 2023-08-19
   inherit (pkgs) cordova; # added 2023-08-18
   inherit (pkgs) create-react-app; # added 2023-09-25
diff --git a/pkgs/development/node-packages/node-packages.json b/pkgs/development/node-packages/node-packages.json
index 4a23f5a83649..f6f73df81171 100644
--- a/pkgs/development/node-packages/node-packages.json
+++ b/pkgs/development/node-packages/node-packages.json
@@ -77,7 +77,6 @@
 , "coc-yaml"
 , "coc-yank"
 , "code-theme-converter"
-, "concurrently"
 , "conventional-changelog-cli"
 , "cpy-cli"
 , "create-cycle-app"
diff --git a/pkgs/development/node-packages/node-packages.nix b/pkgs/development/node-packages/node-packages.nix
index 1613637d8afb..0d20ef3b5f01 100644
--- a/pkgs/development/node-packages/node-packages.nix
+++ b/pkgs/development/node-packages/node-packages.nix
@@ -64917,58 +64917,6 @@ in
     bypassCache = true;
     reconstructLock = true;
   };
-  concurrently = nodeEnv.buildNodePackage {
-    name = "concurrently";
-    packageName = "concurrently";
-    version = "8.2.2";
-    src = fetchurl {
-      url = "https://registry.npmjs.org/concurrently/-/concurrently-8.2.2.tgz";
-      sha512 = "1dP4gpXFhei8IOtlXRE/T/4H88ElHgTiUzh71YUmtjTEHMSRS2Z/fgOxHSxxusGHogsRfxNq1vyAwxSC+EVyDg==";
-    };
-    dependencies = [
-      sources."@babel/runtime-7.24.8"
-      sources."ansi-regex-5.0.1"
-      sources."ansi-styles-4.3.0"
-      (sources."chalk-4.1.2" // {
-        dependencies = [
-          sources."supports-color-7.2.0"
-        ];
-      })
-      sources."cliui-8.0.1"
-      sources."color-convert-2.0.1"
-      sources."color-name-1.1.4"
-      sources."date-fns-2.30.0"
-      sources."emoji-regex-8.0.0"
-      sources."escalade-3.1.2"
-      sources."get-caller-file-2.0.5"
-      sources."has-flag-4.0.0"
-      sources."is-fullwidth-code-point-3.0.0"
-      sources."lodash-4.17.21"
-      sources."regenerator-runtime-0.14.1"
-      sources."require-directory-2.1.1"
-      sources."rxjs-7.8.1"
-      sources."shell-quote-1.8.1"
-      sources."spawn-command-0.0.2"
-      sources."string-width-4.2.3"
-      sources."strip-ansi-6.0.1"
-      sources."supports-color-8.1.1"
-      sources."tree-kill-1.2.2"
-      sources."tslib-2.6.3"
-      sources."wrap-ansi-7.0.0"
-      sources."y18n-5.0.8"
-      sources."yargs-17.7.2"
-      sources."yargs-parser-21.1.1"
-    ];
-    buildInputs = globalBuildInputs;
-    meta = {
-      description = "Run commands concurrently";
-      homepage = "https://github.com/open-cli-tools/concurrently#readme";
-      license = "MIT";
-    };
-    production = true;
-    bypassCache = true;
-    reconstructLock = true;
-  };
   conventional-changelog-cli = nodeEnv.buildNodePackage {
     name = "conventional-changelog-cli";
     packageName = "conventional-changelog-cli";
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 6d08ebeca01e..818bd5d80cda 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -3442,8 +3442,6 @@ with pkgs;
 
   bitwarden-menu = python3Packages.callPackage ../applications/misc/bitwarden-menu { };
 
-  inherit (nodePackages) concurrently;
-
   bklk = callPackage ../applications/misc/bklk { };
 
   bkt = callPackage ../tools/misc/bkt {  };