From 0cdbfe30b5eb6537383b582b518af533b2cee4d6 Mon Sep 17 00:00:00 2001
From: Moraxyc <i@qaq.li>
Date: Thu, 27 Jun 2024 00:46:57 +0800
Subject: [PATCH] mosdns: init at 5.3.1

---
 pkgs/by-name/mo/mosdns/package.nix | 53 ++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 pkgs/by-name/mo/mosdns/package.nix

diff --git a/pkgs/by-name/mo/mosdns/package.nix b/pkgs/by-name/mo/mosdns/package.nix
new file mode 100644
index 000000000000..e38eea028551
--- /dev/null
+++ b/pkgs/by-name/mo/mosdns/package.nix
@@ -0,0 +1,53 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  testers,
+  mosdns,
+  stdenv,
+  installShellFiles,
+}:
+
+buildGoModule rec {
+  pname = "mosdns";
+  version = "5.3.1";
+
+  src = fetchFromGitHub {
+    owner = "IrineSistiana";
+    repo = "mosdns";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-QujkDx899GAImEtQE28ru7H0Zym5SYXJbJEfSBkJYjo=";
+  };
+
+  vendorHash = "sha256-0J5hXb1W8UruNG0KFaJBOQwHl2XiWg794A6Ktgv+ObM=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd mosdns \
+      --bash <($out/bin/mosdns completion bash) \
+      --fish <($out/bin/mosdns completion fish) \
+      --zsh <($out/bin/mosdns completion zsh)
+  '';
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = mosdns;
+      command = "${lib.getExe mosdns} version";
+    };
+  };
+
+  meta = {
+    description = "Modular, pluggable DNS forwarder";
+    homepage = "https://github.com/IrineSistiana/mosdns";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ moraxyc ];
+    mainProgram = "mosdns";
+  };
+}