From 4225f640ef7a92272a9bf3ca7f264651ce512123 Mon Sep 17 00:00:00 2001
From: Elliot Cameron <nixpkgs-commits@deshaw.com>
Date: Fri, 18 Oct 2024 15:44:42 -0400
Subject: [PATCH 1/3] remctl: init at 3.18

---
 pkgs/by-name/re/remctl/package.nix | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 pkgs/by-name/re/remctl/package.nix

diff --git a/pkgs/by-name/re/remctl/package.nix b/pkgs/by-name/re/remctl/package.nix
new file mode 100644
index 000000000000..b354440de81a
--- /dev/null
+++ b/pkgs/by-name/re/remctl/package.nix
@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  libevent,
+  krb5,
+  openssl,
+  perl,
+  pkg-config,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "remctl";
+  version = "3.18";
+
+  src = fetchFromGitHub {
+    owner = "rra";
+    repo = "remctl";
+    rev = "release/${finalAttrs.version}";
+    hash = "sha256-4KzNhFswNTwcXrDBAfRyr502zwRQ3FACV8gDfBm7M0A=";
+  };
+
+  # Fix references to /usr/bin/perl in tests and
+  # disable acl/localgroup test that does not work in sandbox.
+  postPatch = ''
+    patchShebangs tests
+    sed -i '\,server/acl/localgroup,d' tests/TESTS
+  '';
+
+  nativeBuildInputs = [
+    autoreconfHook
+    perl
+    pkg-config
+  ];
+
+  buildInputs = [
+    krb5
+    libevent
+    openssl
+  ];
+
+  # Invokes pod2man to create man pages required by Makefile.
+  preConfigure = ''
+    ./bootstrap
+  '';
+
+  makeFlags = [
+    "LD=$(CC)"
+    "REMCTL_PERL_FLAGS='--prefix=$(out)'"
+    "REMCTL_PYTHON_INSTALL='--prefix=$(out)'"
+  ];
+
+  checkTarget = "check-local";
+
+  meta = with lib; {
+    description = "Remote execution tool";
+    homepage = "https://www.eyrie.org/~eagle/software/remctl";
+    mainProgram = "remctl";
+    license = licenses.mit;
+    maintainers = teams.deshaw.members;
+  };
+})

From b34590bec59d39e3bb4421dfbdca7addde290988 Mon Sep 17 00:00:00 2001
From: Elliot Cameron <nixpkgs-commits@deshaw.com>
Date: Fri, 18 Oct 2024 15:45:48 -0400
Subject: [PATCH 2/3] perlPackages.NetRemctl: init at 3.18

---
 .../perl-modules/NetRemctl/default.nix        | 20 +++++++++++++++++++
 pkgs/top-level/perl-packages.nix              |  2 ++
 2 files changed, 22 insertions(+)
 create mode 100644 pkgs/development/perl-modules/NetRemctl/default.nix

diff --git a/pkgs/development/perl-modules/NetRemctl/default.nix b/pkgs/development/perl-modules/NetRemctl/default.nix
new file mode 100644
index 000000000000..78ee5dfdffcb
--- /dev/null
+++ b/pkgs/development/perl-modules/NetRemctl/default.nix
@@ -0,0 +1,20 @@
+{
+  buildPerlModule,
+  remctl,
+  TestPod,
+}:
+
+buildPerlModule {
+  pname = "NetRemctl";
+
+  inherit (remctl) meta src version;
+
+  postPatch = ''
+    cp -R tests/tap/perl/Test perl/t/lib
+    cd perl
+  '';
+
+  buildInputs = [ remctl ];
+
+  checkInputs = [ TestPod ];
+}
diff --git a/pkgs/top-level/perl-packages.nix b/pkgs/top-level/perl-packages.nix
index f1d40ccc835b..8235d8fca93c 100644
--- a/pkgs/top-level/perl-packages.nix
+++ b/pkgs/top-level/perl-packages.nix
@@ -19100,6 +19100,8 @@ with self; {
     };
   };
 
+  NetRemctl = callPackage ../development/perl-modules/NetRemctl { };
+
   NetServer = buildPerlPackage {
     pname = "Net-Server";
     version = "2.014";

From 100bad6ad37495d85c69b2b1e8cba48a8a16d16e Mon Sep 17 00:00:00 2001
From: Elliot Cameron <nixpkgs-commits@deshaw.com>
Date: Fri, 18 Oct 2024 15:47:39 -0400
Subject: [PATCH 3/3] python312Packages.remctl: init at 3.18

---
 .../python-modules/remctl/default.nix         | 21 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  4 ++++
 2 files changed, 25 insertions(+)
 create mode 100644 pkgs/development/python-modules/remctl/default.nix

diff --git a/pkgs/development/python-modules/remctl/default.nix b/pkgs/development/python-modules/remctl/default.nix
new file mode 100644
index 000000000000..3e672e9e56d2
--- /dev/null
+++ b/pkgs/development/python-modules/remctl/default.nix
@@ -0,0 +1,21 @@
+{
+  lib,
+  buildPythonPackage,
+  pythonOlder,
+  remctl-c, # remctl from pkgs, not from pythonPackages
+  typing,
+}:
+
+buildPythonPackage {
+  inherit (remctl-c)
+    meta
+    pname
+    src
+    version
+    ;
+  setSourceRoot = "sourceRoot=$(echo */python)";
+
+  buildInputs = [ remctl-c ];
+
+  propagatedBuildInputs = lib.optionals (pythonOlder "3.5") [ typing ];
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index e947b31d60cd..7df6e6e7a9eb 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -13552,6 +13552,10 @@ self: super: with self; {
 
   remarshal = callPackage ../development/python-modules/remarshal { };
 
+  remctl = callPackage ../development/python-modules/remctl {
+    remctl-c = pkgs.remctl;
+  };
+
   remi = callPackage ../development/python-modules/remi { };
 
   remote-pdb = callPackage ../development/python-modules/remote-pdb { };