From 80aced8d5cb1612e18f4d3d943810c654f1ba921 Mon Sep 17 00:00:00 2001
From: nat <nat@nekopon.pl>
Date: Thu, 9 Nov 2023 18:27:52 +0100
Subject: [PATCH] jazz2{,-content}: 2.1.0 -> 2.2.2, refactor

---
 pkgs/by-name/ja/jazz2-content/package.nix     | 16 ++++++
 .../ja}/jazz2/nocontent.patch                 |  0
 pkgs/by-name/ja/jazz2/package.nix             | 55 +++++++++++++++++++
 pkgs/games/jazz2/content.nix                  | 20 -------
 pkgs/games/jazz2/game.nix                     | 47 ----------------
 pkgs/top-level/all-packages.nix               |  4 --
 6 files changed, 71 insertions(+), 71 deletions(-)
 create mode 100644 pkgs/by-name/ja/jazz2-content/package.nix
 rename pkgs/{games => by-name/ja}/jazz2/nocontent.patch (100%)
 create mode 100644 pkgs/by-name/ja/jazz2/package.nix
 delete mode 100644 pkgs/games/jazz2/content.nix
 delete mode 100644 pkgs/games/jazz2/game.nix

diff --git a/pkgs/by-name/ja/jazz2-content/package.nix b/pkgs/by-name/ja/jazz2-content/package.nix
new file mode 100644
index 000000000000..d30f6a771b23
--- /dev/null
+++ b/pkgs/by-name/ja/jazz2-content/package.nix
@@ -0,0 +1,16 @@
+{ jazz2
+, lib
+, runCommandLocal
+}:
+
+runCommandLocal "jazz2-content"
+{
+  inherit (jazz2) version src;
+
+  meta = (builtins.removeAttrs jazz2.meta ["mainProgram"]) // {
+    description = "Assets needed for jazz2";
+    platforms = lib.platforms.all;
+  };
+} ''
+  cp -r $src/Content $out
+''
diff --git a/pkgs/games/jazz2/nocontent.patch b/pkgs/by-name/ja/jazz2/nocontent.patch
similarity index 100%
rename from pkgs/games/jazz2/nocontent.patch
rename to pkgs/by-name/ja/jazz2/nocontent.patch
diff --git a/pkgs/by-name/ja/jazz2/package.nix b/pkgs/by-name/ja/jazz2/package.nix
new file mode 100644
index 000000000000..5b95bb8c1875
--- /dev/null
+++ b/pkgs/by-name/ja/jazz2/package.nix
@@ -0,0 +1,55 @@
+{ cmake
+, fetchFromGitHub
+, glfw
+, jazz2-content
+, lib
+, libopenmpt
+, libvorbis
+, openal
+, SDL2
+, stdenv
+, testers
+, zlib
+, graphicsLibrary ? "GLFW"
+}:
+
+assert lib.assertOneOf "graphicsLibrary" graphicsLibrary [ "SDL2" "GLFW" ];
+stdenv.mkDerivation (finalAttrs: {
+  pname = "jazz2";
+  version = "2.2.2";
+
+  src = fetchFromGitHub {
+    owner = "deathkiller";
+    repo = "jazz2-native";
+    rev = finalAttrs.version;
+    hash = "sha256-1psMeuMV8GjS+uNlgtCvKpHgV9XW+vjviQTHBPjA4Lc=";
+  };
+
+  patches = [ ./nocontent.patch ];
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ libopenmpt libvorbis openal zlib ]
+  ++ lib.optionals (graphicsLibrary == "GLFW") [ glfw ]
+  ++ lib.optionals (graphicsLibrary == "SDL2") [ SDL2 ];
+
+  cmakeFlags = [
+    "-DLIBOPENMPT_INCLUDE_DIR=${lib.getDev libopenmpt}/include/libopenmpt"
+    "-DNCINE_DOWNLOAD_DEPENDENCIES=OFF"
+    "-DNCINE_OVERRIDE_CONTENT_PATH=${jazz2-content}"
+  ] ++ lib.optionals (graphicsLibrary == "GLFW") [
+    "-DGLFW_INCLUDE_DIR=${glfw}/include/GLFW"
+  ];
+
+  passthru.tests.version = testers.testVersion {
+    package = finalAttrs.finalPackage;
+  };
+
+  meta = with lib; {
+    description = "Open-source Jazz Jackrabbit 2 reimplementation";
+    homepage = "https://github.com/deathkiller/jazz2-native";
+    license = licenses.gpl3Only;
+    mainProgram = "jazz2";
+    maintainers = with maintainers; [ surfaceflinger ];
+    platforms = platforms.linux;
+  };
+})
diff --git a/pkgs/games/jazz2/content.nix b/pkgs/games/jazz2/content.nix
deleted file mode 100644
index 0a0e72075635..000000000000
--- a/pkgs/games/jazz2/content.nix
+++ /dev/null
@@ -1,20 +0,0 @@
-{ jazz2
-, lib
-, runCommand
-}:
-
-runCommand "jazz2-content"
-{
-  inherit (jazz2) version src;
-
-  preferLocalBuild = true;
-
-  meta = with lib; {
-    description = "Assets needed for jazz2";
-    homepage = "https://github.com/deathkiller/jazz2-native";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ surfaceflinger ];
-  };
-} ''
-  cp -r $src/Content $out
-''
diff --git a/pkgs/games/jazz2/game.nix b/pkgs/games/jazz2/game.nix
deleted file mode 100644
index 22ddbfe337a7..000000000000
--- a/pkgs/games/jazz2/game.nix
+++ /dev/null
@@ -1,47 +0,0 @@
-{ cmake
-, fetchFromGitHub
-, glew
-, glfw
-, jazz2-content
-, lib
-, libGL
-, libopenmpt
-, libvorbis
-, openal
-, SDL2
-, stdenv
-, xorg
-, zlib
-}:
-
-stdenv.mkDerivation rec {
-  pname = "jazz2";
-  version = "2.1.0";
-
-  src = fetchFromGitHub {
-    owner = "deathkiller";
-    repo = "jazz2-native";
-    rev = version;
-    sha256 = "nJha7+geP2Ov7ciEDzJ+XWdiF1jzv4Oeis1DwxcpJXo=";
-  };
-
-  patches = [ ./nocontent.patch ];
-
-  buildInputs = [ libGL SDL2 zlib glew glfw openal libvorbis libopenmpt xorg.libSM xorg.libICE xorg.libXext ];
-  nativeBuildInputs = [ cmake ];
-
-  cmakeFlags = [
-    "-DNCINE_DOWNLOAD_DEPENDENCIES=OFF"
-    "-DGLFW_INCLUDE_DIR=${glfw}/include/GLFW"
-    "-DLIBOPENMPT_INCLUDE_DIR=${libopenmpt.dev}/include/libopenmpt"
-    "-DNCINE_OVERRIDE_CONTENT_PATH=${jazz2-content}"
-  ];
-
-  meta = with lib; {
-    description = "Open-source Jazz Jackrabbit 2 reimplementation";
-    homepage = "https://github.com/deathkiller/jazz2-native";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ surfaceflinger ];
-    platforms = platforms.linux;
-  };
-}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index af609d1e8a3a..9236aa1ee295 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -37774,10 +37774,6 @@ with pkgs;
 
   fish-fillets-ng = callPackage ../games/fish-fillets-ng { };
 
-  jazz2 = callPackage ../games/jazz2/game.nix { };
-
-  jazz2-content = callPackage ../games/jazz2/content.nix { };
-
   jumpy = callPackage ../games/jumpy { };
 
   flightgear = libsForQt5.callPackage ../games/flightgear { };