mirror of
https://github.com/NixOS/nix.git
synced 2025-02-21 11:22:35 +00:00
46a369ad95
For example, given a derivation with outputs "out", "man" and "bin": $ nix-build -A pkg produces ./result pointing to the "out" output; $ nix-build -A pkg.man produces ./result-man pointing to the "man" output; $ nix-build -A pkg.all produces ./result, ./result-man and ./result-bin; $ nix-build -A pkg.all -A pkg2 produces ./result, ./result-man, ./result-bin and ./result-2.
28 lines
720 B
Nix
28 lines
720 B
Nix
/* This is the implementation of the ‘derivation’ builtin function.
|
||
It's actually a wrapper around the ‘derivationStrict’ primop. */
|
||
|
||
drvAttrs @ { outputs ? [ "out" ], ... }:
|
||
|
||
let
|
||
|
||
strict = derivationStrict drvAttrs;
|
||
|
||
commonAttrs = drvAttrs // (builtins.listToAttrs outputsList) //
|
||
{ all = map (x: x.value) outputsList;
|
||
inherit drvAttrs;
|
||
};
|
||
|
||
outputToAttrListElement = outputName:
|
||
{ name = outputName;
|
||
value = commonAttrs // {
|
||
outPath = builtins.getAttr outputName strict;
|
||
drvPath = strict.drvPath;
|
||
type = "derivation";
|
||
inherit outputName;
|
||
};
|
||
};
|
||
|
||
outputsList = map outputToAttrListElement outputs;
|
||
|
||
in (builtins.head outputsList).value
|